Hardcore Gamer Resource Kit/Hardcore Gamer Resource Kit - Disc 2.iso/Pc/K_O/MERC106P.ZIP/TOOLS/STRIP1.BAT

DOS Batch File | 1996-11-14 | 1KB | 31 lines

@if not #%1 == # goto ok
@echo Usage: strip1 worlddir
@echo Must be run from your Mercenaries' TOOLS subdirectory.
@echo WORLDDIR must be a subdirectory inside the TOOLS subdirectory.
@goto end
:ok
@if exist stripwld.exe goto ok2
@echo Error: stripwld.exe not found!  You must run this from \MERCS\TOOLS.
@goto end
:ok2
@if exist ..\mw2.prj goto ok3
@echo Error: ..\mw2.prj not found!  You must run this from \MERCS\TOOLS.
@goto end
:ok3
@if exist en00star.bwd goto ok4
@echo Error: en00star.bwd not found!  You need to copy *.bwd from the CD's \TOOLS folder!
@goto end
:ok4
@rem The first line that really does anything: figure out what to WASM.
.\stripwld -t %1 .. > %1.bat
@if errorlevel 1 echo Error running STRIPWLD on %1!
@if errorlevel 1 goto end
@rem The second line that really does anything: actually run WASM and make the .mwm.
call %1
@if errorlevel 1 echo Error running STRIPWLD or WASM on %1!
@if errorlevel 1 goto end
@rem The third line that really does anything: move the .mwm to where it can be run.
move *.mwm ..\missions
@if errorlevel 1 echo Error moving *.mwm to ..\missions!
:end